「DataGridView」の記事 - Crieit

【VB.NET】DataGridView の行を動的に追加してみる

2019-10-03T09:28:32+09:00

引き続き、DataGridView関連の話し。
今回は行を動的に追加する方法を試してみてました。

プログラムは前回のものを流用します。
【VB.NET】DataGridView を直接変更してデータを更新してみる

プログラム修正

追加処理

追加ボタンが押されたタイミングで、データグリッドビューの空行を作成して追加します。

今回は、1行追加したら「更新」するまで追加できないようにしました。
（グローバルでフラグを持たせています）

    ''' 
    ''' 追加ボタンクリックイベント
    ''' 
    ''' 
    ''' 
    Private Sub btnAdd_Click(sender As Object, e As EventArgs) Handles btnAdd.Click

        ' 追加後に更新されていなければ処理しない
        If (AddRowFlg) Then
            Return
        End If

        AddRowFlg = True

        Using conn As New SQLiteConnection("Data Source=SampleDb.sqlite")

            ' データベースオープン
            conn.Open()

            ' データ追加
            Using con As New DataContext(conn)

                Dim idx = dgvCat.Rows.Count()

                ' 行追加
                dgvCat.Rows.Add()

                ' 種別マスタ取得
                Dim kinds As Table(Of Kind) = con.GetTable(Of Kind)
                Dim kindResult As IQueryable(Of Kind) = From x In kinds Order By x.KindCd Select x
                Dim kindList = kindResult.ToList()

                ' 猫一覧取得
                Dim tblCat As Table(Of Cat) = con.GetTable(Of Cat)
                Dim newNo = 0

                ' 使用できるNoを判定
                For i As Integer = 1 To tblCat.ToList().Count() + 1
                    Dim selectNo = i
                    If tblCat.SingleOrDefault(Function(x As Cat) x.No = selectNo) Is Nothing Then
                        newNo = selectNo
                    End If
                Next

                ' No（プライマリなので編集不可）
                Dim no = New DataGridViewTextBoxCell()
                no.Value = newNo
                dgvCat(0, idx) = no
                dgvCat(0, idx).ReadOnly = True

                ' 名前
                Dim name = New DataGridViewTextBoxCell()
                dgvCat(1, idx) = name

                ' 性別
                Dim sex = New DataGridViewComboBoxCell()
                sex.Items.AddRange({"♂", "♀"})
                sex.DisplayStyle = DataGridViewComboBoxDisplayStyle.ComboBox
                dgvCat(2, idx) = sex

                ' 年齢
                Dim age = New DataGridViewTextBoxCell()
                dgvCat(3, idx) = age

                ' 種別
                Dim kind = New DataGridViewComboBoxCell()
                kind.DataSource = kindList
                kind.DisplayMember = "KindName"
                kind.ValueMember = "KindCd"
                kind.DisplayStyle = DataGridViewComboBoxDisplayStyle.ComboBox
                dgvCat(4, idx) = kind

                ' 好物
                Dim favorite = New DataGridViewTextBoxCell()
                dgvCat(5, idx) = favorite

            End Using

            conn.Close()

        End Using

    End Sub

更新処理

更新処理では、データグリッドビューから直接値を取得して、データベースに存在しなければ追加、存在すれば更新というようにしました。

    ''' 
    ''' 更新ボタンクリックイベント
    ''' 
    ''' 
    ''' 
    Private Sub btnUpdate_Click(sender As Object, e As EventArgs) Handles btnUpdate.Click

        Using conn As New SQLiteConnection("Data Source=SampleDb.sqlite")

            ' データベースオープン
            conn.Open()

            ' データ更新
            Using con As New DataContext(conn)
                ' 対象のテーブルオブジェクトを取得
                Dim Table = con.GetTable(Of Cat)
                ' 選択されているデータを取得
                For i = 0 To dgvCat.Rows.Count - 1
                    ' テーブルから対象のデータを取得
                    Dim no As Integer = dgvCat(0, i).Value
                    Dim target As Cat = Table.SingleOrDefault(Function(x As Cat) x.No = no)
                    If (target Is Nothing) Then
                        ' データ作成
                        Dim Cat As New Cat()
                        Cat.No = dgvCat(0, i).Value
                        Cat.Name = dgvCat(1, i).Value
                        Cat.Sex = dgvCat(2, i).Value
                        Cat.Age = dgvCat(3, i).Value
                        Cat.KindCd = dgvCat(4, i).Value
                        Cat.Favorite = dgvCat(5, i).Value
                        Table.InsertOnSubmit(Cat)

                    Else

                        ' データ変更
                        target.Name = dgvCat(1, i).Value
                        target.Sex = dgvCat(2, i).Value
                        target.Age = dgvCat(3, i).Value
                        target.KindCd = dgvCat(4, i).Value
                        target.Favorite = dgvCat(5, i).Value

                    End If
                    ' DBの変更を確定
                    con.SubmitChanges()
                Next

            End Using

            conn.Close()
        End Using

        AddRowFlg = False

        ' データ再検索
        search()
        MessageBox.Show("データを更新しました。")

    End Sub

起動してみる

とりあえず検索します。

追加ボタンをクリックすると空行が追加されます。

追加された行に値を設定します。

更新ボタンをクリック、再検索後の画面が表示されます。

まとめ

年の瀬となり忙しくなってまいりましたが
なんとか更新していきたいと思います。

次回はどうしようかな。。

ではでは。

【VB.NET】DataGridView を直接変更してデータを更新してみる

2019-10-02T09:28:19+09:00

今回は、データグリッドビューの内容を直接編集してデータを更新したいと思います。

プログラムは例によって前回のものを。
【VB.NET】SQLiteに接続してデータを登録してみる

プログラム修正

検索処理

取得したデータを走査して1行ずつ作成していくように変更します。

        ''' 
        ''' 検索処理
        ''' 
        Private Sub search()
            Using conn As New SQLiteConnection("Data Source=SampleDb.sqlite")

                ' データベースオープン
                conn.Open()

                ' 検索条件を指定してデータを取得
                Using con As New DataContext(conn)
                    Dim searchName As String = txtName.Text
                    Dim searchKind As String = CType(cmbKind.SelectedValue, Kind).KindCd

                    ' 種別マスタ取得
                    Dim kinds As Table(Of Kind) = con.GetTable(Of Kind)
                    Dim kindResult As IQueryable(Of Kind) = From x In kinds Order By x.KindCd Select x
                    Dim kindList = kindResult.ToList()

                    ' 猫一覧取得
                    Dim tblCat As Table(Of Cat) = con.GetTable(Of Cat)
                    Dim result As IQueryable(Of Cat)

                    If (searchKind = "") Then

                        ' 種別が選択されていなければ名前のみ前方一致指定
                        result = From x In tblCat
                                 Where x.Name.StartsWith(searchName)
                                 Order By x.No
                                 Select x
                    Else

                        ' 種別が選択されていれば名前＋種別で検索
                        result = From x In tblCat
                                 Where x.Name.StartsWith(searchName) & x.KindCd = searchKind
                                 Order By x.No
                                 Select x
                    End If

                    ' データグリッドビューに設定
                    'dgvCat.DataSource = result.ToList()
                    Dim list As List(Of Cat) = result.ToList()
                    Dim i As Integer = 0
                    dgvCat.Rows.Clear()
                    For i = 0 To list.Count() - 1

                        Dim cat = list(i)

                        ' 行追加
                        dgvCat.Rows.Add()

                        ' No（プライマリなので編集不可）
                        Dim no = New DataGridViewTextBoxCell()
                        no.Value = cat.No
                        dgvCat(0, i) = no
                        dgvCat(0, i).ReadOnly = True

                        ' 名前
                        Dim name = New DataGridViewTextBoxCell()
                        name.Value = cat.Name
                        dgvCat(1, i) = name

                        ' 性別
                        Dim sex = New DataGridViewComboBoxCell()
                        sex.Items.AddRange({"♂", "♀"})
                        sex.DisplayStyle = DataGridViewComboBoxDisplayStyle.ComboBox
                        dgvCat(2, i) = sex
                        dgvCat(2, i).Value = cat.Sex

                        ' 年齢
                        Dim age = New DataGridViewTextBoxCell()
                        age.Value = cat.Age
                        dgvCat(3, i) = age

                        ' 種別
                        Dim kind = New DataGridViewComboBoxCell()
                        kind.DataSource = kindList
                        kind.DisplayMember = "KindName"
                        kind.ValueMember = "KindCd"
                        kind.DisplayStyle = DataGridViewComboBoxDisplayStyle.ComboBox
                        dgvCat(4, i) = kind
                        dgvCat(4, i).Value = cat.KindCd

                        ' 好物
                        Dim favorite = New DataGridViewTextBoxCell()
                        favorite.Value = cat.Favorite
                        dgvCat(5, i) = favorite

                    Next

                End Using

                ' データベースクローズ
                conn.Close()

            End Using
        End Sub

更新処理

データグリッドビューに表示されているデータを全て更新するように変更します。

    ''' 
    ''' 更新ボタンクリックイベント
    ''' 
    ''' 
    ''' 
    Private Sub btnUpdate_Click(sender As Object, e As EventArgs) Handles btnUpdate.Click

        Using conn As New SQLiteConnection("Data Source=SampleDb.sqlite")

            ' データベースオープン
            conn.Open()

            ' データ更新
            Using con As New DataContext(conn)
                ' 対象のテーブルオブジェクトを取得
                Dim Table = con.GetTable(Of Cat)
                ' 選択されているデータを取得
                For i = 0 To dgvCat.Rows.Count - 1
                    ' テーブルから対象のデータを取得
                    Dim no As Integer = dgvCat(0, i).Value
                    Dim target As Cat = Table.Single(Function(x As Cat) x.No = no)
                    ' データ変更
                    target.Name = dgvCat(1, i).Value
                    target.Sex = dgvCat(2, i).Value
                    target.Age = dgvCat(3, i).Value
                    target.KindCd = dgvCat(4, i).Value
                    target.Favorite = dgvCat(5, i).Value
                    ' DBの変更を確定
                    con.SubmitChanges()
                Next

            End Using

            conn.Close()
        End Using

        ' データ再検索
        search()
        MessageBox.Show("データを更新しました。")

    End Sub

コンボボックスの制御

以前の記事でもやりましたが、
コンボボックスがワンクリックで開くように仕込みを入れます。

    ''' 
    ''' データグリッドビューセルクリックイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgvCat_CellClick(sender As Object, e As DataGridViewCellEventArgs) Handles dgvCat.CellClick
        Dim dgv As DataGridView = CType(sender, DataGridView)
        gridComboHandle(dgv, e)
    End Sub

    ''' 
    ''' データグリッドビューのコンボボックス制御
    ''' 
    ''' 
    ''' 
    Private Sub gridComboHandle(dgv As DataGridView, e As DataGridViewCellEventArgs)

        ' 対象の列だった場合
        If dgv.Columns(e.ColumnIndex).Name = "ColSex" Or dgv.Columns(e.ColumnIndex).Name = "ColKind" Then
            SendKeys.SendWait("{F4}")
        End If

    End Sub

起動してみる

データ検索後の画面。
無事にデータが表示され、データグリッドビューにコンボボックスも表示されています。

1行目の種別を変更して、「更新」ボタンをクリックします。

無事に変更できました。

まとめ

やり方としてはいまいちで、WPFみたいにMVVMとかバインディングとかできるかと思いますが、これはこれでもしかしたら需要があるかもしれません。

次回は追加処理をしてみます。

ではでは。

【VB.NET】データグリッドビューでチェックされた行の背景色を変更する

2019-09-20T09:23:00+09:00

引き続きVB.NETの話し。
せっかくチェックボックスにイベントを仕込んだのでそれをトリガーにして背景色を変更する処理を実装したいと思います。

プログラムは下記のものを流用します。
【VB.NET】データグリッドビューで行毎のチェックボックスにイベントを仕込む## プログラムの修正

背景色の定義を追加

グローバルの定数として背景色を定義します。

Form1.vb

    ' 通常時の背景色
    Private Const BG_NORMAL = "#FFFFFF"
    ' 強調時の背景色
    Private Const BG_HIGHLIGHT = "#FFE7E7"
    ' 選択時の背景色
    Private Const BG_SELECTED = "#EF9A94"

既存処理の修正

データグリッドビューのセル値が変更（が確定）された際のイベントで背景色を変更します。

Form1.vb

    ''' 
    ''' データグリッドビューのセル値が変更（が確定）された際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CellValueChanged(sender As Object, e As DataGridViewCellEventArgs) Handles dgv.CellValueChanged

        If (TypeOf dgv(e.ColumnIndex, e.RowIndex) Is DataGridViewCheckBoxCell) Then
            Dim chk As DataGridViewCheckBoxCell = dgv(e.ColumnIndex, e.RowIndex)
            Dim dgs = New DataGridViewCellStyle()
            If (chk.Value = True) Then
                dgs.BackColor = System.Drawing.ColorTranslator.FromHtml(BG_SELECTED)
            Else
                dgs.BackColor = System.Drawing.ColorTranslator.FromHtml(BG_NORMAL)
            End If
            dgv.Rows(e.RowIndex).DefaultCellStyle = dgs
        End If
    End Sub

新規イベントの追加

CellMouseEnter、CellMouseLeaveの２つを追加します。

マウスオーバーした際に背景色を変更して強調します。

Form1.vb

    ''' 
    ''' データグリッドビューのセルにマウスポインターがフォーカスした際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CellMouseEnter(sender As Object, e As DataGridViewCellEventArgs) Handles dgv.CellMouseEnter
        ' ヘッダーは処理しない
        If e.ColumnIndex >= 0 And e.RowIndex >= 0 Then
            Dim dgv As DataGridView = CType(sender, DataGridView)
            ' 背景色を変更する
            dgv.Rows(e.RowIndex).DefaultCellStyle.BackColor = System.Drawing.ColorTranslator.FromHtml(BG_HIGHLIGHT)
        End If
    End Sub

    ''' 
    ''' データグリッドビューのセルからマウスポインターがフォーカスアウトした際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CellMouseLeave(sender As Object, e As DataGridViewCellEventArgs) Handles dgv.CellMouseLeave
        ' ヘッダーは処理しない
        If e.ColumnIndex >= 0 And e.RowIndex >= 0 Then
            Dim dgv As DataGridView = CType(sender, DataGridView)
            If (dgv(0, e.RowIndex).Value) Then
                ' 選択された状態に戻す
                dgv.Rows(e.RowIndex).DefaultCellStyle.BackColor = System.Drawing.ColorTranslator.FromHtml(BG_SELECTED)
            Else
                ' 背景色を戻す
                dgv.Rows(e.RowIndex).DefaultCellStyle.BackColor = System.Drawing.ColorTranslator.FromHtml(BG_NORMAL)
            End If
        End If
    End Sub

起動してみる

マウスポインターがある行が強調表示されます。

チェックすると選択された行の背景色が変わります。

無事にマウスオーバーで強調表示、チェックボックスにチェックで選択表示ができました。

まとめ

C#と同様、VB.NETでも色々な事ができそうです。
せっかくなので、この後はまたデータベースからデータをひっぱってきたりってのをやろうかと思います。

ではでは。

【VB.NET】データグリッドビューで行毎のチェックボックスにイベントを仕込む

2019-09-13T09:40:08+09:00

今回は、データグリッドに配置したチェックボックス列にイベントを仕込みたいと思います。

プログラムは前回のものを流用。
【VB.NET】データグリッドビューで行毎のコンボボックスにイベントを仕込む

プログラムの修正

新規イベントの追加

データグリッドビューの現在のセル状態が変更された際のイベントを追加します。

Form1.vb

    ''' 
    ''' データグリッドビューの現在のセル状態が変更された際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CurrentCellDirtyStateChanged(sender As Object, e As EventArgs) Handles dgv.CurrentCellDirtyStateChanged
        ' 対象のセルを判定
        If dgv.CurrentCellAddress.X = 0 AndAlso dgv.IsCurrentCellDirty Then
            ' 変更を確定する
            dgv.CommitEdit(DataGridViewDataErrorContexts.Commit)
        End If
    End Sub

データグリッドビューのセル値が変更された際のイベントを追加

Form1.vb

    ''' 
    ''' データグリッドビューのセル値が変更（が確定）された際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CellValueChanged(sender As Object, e As DataGridViewCellEventArgs) Handles dgv.CellValueChanged

        If (TypeOf dgv(e.ColumnIndex, e.RowIndex) Is DataGridViewCheckBoxCell) Then
            Dim chk As DataGridViewCheckBoxCell = dgv(e.ColumnIndex, e.RowIndex)
            MessageBox.Show(e.RowIndex + 1 & "行目のチェックボックス値：" & chk.Value)
        End If

    End Sub

データグリッドビューのセルがクリック（マウスダウン）された際のイベントを追加

Form1.vb

    ''' 
    ''' データグリッドビューのセルをクリック（マウスダウン）した際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CellMouseDown(sender As Object, e As DataGridViewCellMouseEventArgs) Handles dgv.CellMouseDown
        If (TypeOf dgv(e.ColumnIndex, e.RowIndex) Is DataGridViewCheckBoxCell) Then
            Dim cell As DataGridViewCheckBoxCell = dgv(e.ColumnIndex, e.RowIndex)
            cell.Value = If(cell.Value = False, True, False)
            ' 変更を確定する
            dgv.CommitEdit(DataGridViewDataErrorContexts.Commit)
            dgv.EndEdit()
        End If
    End Sub

起動してみる

無事に処理できましたね。

まとめ

次回は、チェックされた行の背景色を変更してみたいと思います。

【VB.NET】データグリッドビューでチェックされた行の背景色を変更する

ではでは。

【VB.NET】データグリッドビューで行毎のコンボボックスにイベントを設定する

2019-09-11T09:55:11+09:00

引き続きVB.NETの話し。
今回はデータグリッドビューに配置したコンボボックスにイベントを設定するといったことをやってみます。

プログラムは前回のものを流用します。
【VB.NET】データグリッドビューを動的に作成する

プログラムの修正

新規メソッド追加

ドロップダウンが（選択されて）閉じられた際の処理を新規メソッドで定義

Form1.vb

    ''' 
    ''' データグリッドビューのコンボボックスが閉じられた際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dataGridViewComboBox_DropDownClosed(ByVal sender As Object,
                ByVal e As EventArgs)
        Dim cb As DataGridViewComboBoxEditingControl =
            DirectCast(sender, DataGridViewComboBoxEditingControl)
        cb.EditingControlDataGridView.NotifyCurrentCellDirty(True)

        ' 行ごとに処理を変更する
        If cb.EditingControlRowIndex = 0 Then
            MessageBox.Show("1行目のコンボボックス：" & cb.SelectedItem)
        ElseIf cb.EditingControlRowIndex = 1 Then
            MessageBox.Show("2行目のコンボボックス：" & cb.SelectedItem)
        ElseIf cb.EditingControlRowIndex = 2 Then
            MessageBox.Show("3行目のコンボボックス：" & cb.SelectedItem)
        End If
        cb.EditingControlDataGridView.EndEdit()
    End Sub

ここで、行インデックスや、列インデックス、または名前などを判定して処理を分岐します。

新規イベント追加

デザイナー画面でデータグリッドビューを選択し、プロパティ画面から対象のイベントを作成します。

データグリッドビューのセル内に設置したコンボボックスの内容が表示された際に、ドロップダウンが（選択されて）閉じられたイベントを追加します。

From1.vb

    ''' 
    ''' 編集中コントロールが表示されている際のイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_EditingControlShowing(sender As Object, e As DataGridViewEditingControlShowingEventArgs) Handles dgv.EditingControlShowing
        Dim cb = TryCast(e.Control, DataGridViewComboBoxEditingControl)
        If cb Is Nothing Then Return
        RemoveHandler cb.DropDownClosed, AddressOf dataGridViewComboBox_DropDownClosed
        AddHandler cb.DropDownClosed, AddressOf dataGridViewComboBox_DropDownClosed
    End Sub

既存処理の修正

データグリッド内のコンボボックスを選択した際に、
同じコンボボックスを連続でクリックすると正しく開かない問題が発覚したため既存の処理も修正。

Form1.vb

    ''' 
    ''' データグリッドビューセルクリックイベント
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CellClick(sender As Object, e As DataGridViewCellEventArgs) Handles dgv.CellClick
        Dim dgv As DataGridView = CType(sender, DataGridView)
        gridComboHandle(dgv, e)
    End Sub

    ''' 
    ''' データグリッドビューのコンボボックス制御
    ''' 
    ''' 
    ''' 
    Private Sub gridComboHandle(dgv As DataGridView, e As DataGridViewCellEventArgs)

        ' 対象の列だった場合
        If dgv.Columns(e.ColumnIndex).Name = "col3" Then
            SendKeys.SendWait("{F4}")
        End If

    End Sub

データグリッドビューのセルエンターイベントで処理していたのを、
セルクリックに変更して、更に「SendKey.Send」を「SendKey.SendWait」に変更。

起動してみる

起動後の画面です。

コンボボックスを選択します。

イベントが処理され、メッセージボックスが表示されました。

まとめ

データグリッドビューにコンポーネントを配置するってよくある話しだと思うんですが、何で標準でもっと便利にしてくれないんでしょうかね。

ちょっとハマった部分は、コンボボックスを1回で開くところですね。
まあなんとかなってよかったです。

また何かあれば記事にしようと思います。

ではでは。

【VB.NET】データグリッドビューを動的に作成して行毎に違う内容のコンボボックスを表示する

2019-09-10T09:47:55+09:00

ちょっと仕事の関係でVB.NETを使う機会があったので、備忘的な記事になります。

完全にデータグリッドビューの使い方からは外れてしまうのかもしれませんが、
行ごとに別の内容のコンボボックスを表示するといったことをやりました。

まずはサンプルプロジェクトの作成から。

プロジェクトの新規作成

VisualStudio2017 を起動し、上部メニューの「ファイル」＞「新規作成」＞「プロジェクト」を選択します。

新しいプロジェクト作成ウィザードが表示されるので、
「Visual Basic」＞「Windowsフォームアプリケーション」を選択、名前を入力して「OK」ボタンをクリックします。

作成後はデザイナー画面が表示されます。

とりあえずプロジェクトの作成はこれで完了です。

データグリッドビューの配置

ツールボックスから「DataGridView」を選択して画面に配置します。
サイズなんかはとりあえず適当で大丈夫です。

名前の設定

プロパティから、「Name」の項目に「dgv」を設定しておきます。
（コードビハインドから操作する際にこの項目を使用します）

イベントの追加

データグリッドビューを選択した状態でプロパティから、イベントメニューを選択、
「Load」の項目をダブルクリックして起動時の処理を追加します。

また、データグリッドビューのセルに設置するコンボボックスのために、
「CellEnter」の項目もイベントを追加しておきます。

処理の実装

Form1.vb（コード）に、プログラムを記述します。

ロードイベント

    ''' 
    ''' フォームロードイベント.
    ''' 
    ''' 
    ''' 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

        Dim mainList As String() = {"ユーザー", "集客", "行動", "コンバージョン"}
        Dim userList As String() = {"アクティブユーザー", "ライフタイムバリュー", "コポート分析"}
        Dim syukyakuList As String() = {"全てのトラフィック", "AdWords", "Search Console"}
        Dim koudouList As String() = {"行動フロー", "サイトコンテンツ", "サイトの速度"}

        ' データグリッドの設定
        dgv.AllowUserToAddRows = False
        dgv.AllowUserToResizeRows = False
        dgv.AllowUserToResizeColumns = False
        dgv.RowHeadersVisible = False

        ' ヘッダースタイル定義（共通）
        Dim headerStyle As New DataGridViewCellStyle()
        headerStyle.Alignment = DataGridViewContentAlignment.MiddleCenter

        ' チェックボックス列追加
        Dim checkCol As DataGridViewTextBoxColumn = New DataGridViewTextBoxColumn()
        checkCol.HeaderCell.Style = headerStyle
        checkCol.HeaderText = "選択"
        checkCol.Name = "col1"
        checkCol.DataPropertyName = "col1"
        checkCol.Width = 40
        dgv.Columns.Add(checkCol)

        ' スタイル設定
        Dim checkStyle As New DataGridViewCellStyle()
        checkStyle.Alignment = DataGridViewContentAlignment.MiddleCenter
        checkCol.DefaultCellStyle = checkStyle

        ' テキスト列追加
        Dim textCol As DataGridViewTextBoxColumn = New DataGridViewTextBoxColumn()
        textCol.HeaderCell.Style = headerStyle
        textCol.HeaderText = "メニュー"
        textCol.Name = "col2"
        textCol.DataPropertyName = "col2"
        textCol.Width = 120
        dgv.Columns.Add(textCol)

        ' コンボボックス列の追加
        Dim cbCol As DataGridViewTextBoxColumn = New DataGridViewTextBoxColumn()
        cbCol.HeaderCell.Style = headerStyle
        cbCol.HeaderText = "項目"
        cbCol.Name = "col3"
        cbCol.DataPropertyName = "col3"
        cbCol.Width = 150
        dgv.Columns.Add(cbCol)

        Dim i As Short
        For i = 0 To mainList.Length - 1

            ' 行追加
            dgv.Rows.Add()

            ' チェックボックス
            Dim chk As New DataGridViewCheckBoxCell()
            chk.Value = False
            dgv(0, i) = chk

            ' テキストボックス
            Dim txt As New DataGridViewTextBoxCell()
            txt.Value = mainList(i)
            dgv(1, i) = txt

            Dim cmb As New DataGridViewComboBoxCell()
            If (mainList(i) = "ユーザー") Then
                cmb.Items.AddRange(userList)
                dgv(2, i) = cmb
                dgv(2, i).Value = userList(0)
            ElseIf (mainList(i) = "集客") Then
                cmb.Items.AddRange(syukyakuList)
                dgv(2, i) = cmb
                dgv(2, i).Value = syukyakuList(0)
            ElseIf (mainList(i) = "行動") Then
                cmb.Items.AddRange(koudouList)
                dgv(2, i) = cmb
                dgv(2, i).Value = koudouList(0)
            ElseIf (mainList(i) = "コンバージョン") Then
                ' コンボボックスを設定しない
            End If
        Next
    End Sub

データグリッドビューのセルエンターイベント

    ''' 
    ''' データグリッドビューセルエンターイベント.
    ''' 
    ''' 
    ''' 
    Private Sub dgv_CellEnter(sender As Object, e As DataGridViewCellEventArgs) Handles dgv.CellEnter
        ' データグリッドビューを取得
        Dim dgv As DataGridView = CType(sender, DataGridView)
        gridComboHandle(dgv, e)
    End Sub

データグリッドビューのコンボボックス制御

通常だと、データグリッドビューに設置したコンボボックスは一回のクリックで開いてくれない。
それをなんとかするための措置。

    ''' 
    ''' データグリッドビューのコンボボックス制御
    ''' 
    ''' 
    ''' 
    Private Sub gridComboHandle(dgv As DataGridView, e As DataGridViewCellEventArgs)
        ' 対象のグリッドであれば
        If dgv.Columns(e.ColumnIndex).Name = "col3" Then
            SendKeys.Send("{F4}")
        End If

    End Sub

起動してみる

ひとまずグリッドに内容が表示されました。

1行目のコンボボックスの内容です。

2行目のコンボボックスの内容です。

ひとまず目的のことはできましたね。

まとめ

本来であれば、データグリッドビューではなく他のコントローラで実現すべきところなんだと思いますが、顧客からの要望なんかでやらざるをえない場合もありますよね。

何かの参考になれば。

ではでは。

【C#】DataGridView の行選択時にチェックボックスの状態を変更する（その２）

2019-09-08T13:20:10+09:00

前回のものを少し改良しました。

変更したのは主に下記の制御。

ドラッグでの複数選択
Shift または Ctrl を押しながらの選択
チェックボックスを直接チェックした場合の挙動

プログラム

Form1.cs

using System;
using System.Collections.Generic;
using System.ComponentModel;
using System.Data;
using System.Drawing;
using System.Linq;
using System.Text;
using System.Threading.Tasks;
using System.Windows.Forms;

namespace SampleDataGridCheckbox
{
    /// 
    /// サンプルフォーム
    /// 
    public partial class Form1 : Form
    {

        /// 
        /// 初期化処理
        /// 
        public Form1()
        {
            InitializeComponent();

            dataGridView1.Rows.Add(false, "テスト１", "テスト１");
            dataGridView1.Rows.Add(false, "テスト２", "テスト２");
            dataGridView1.Rows.Add(false, "テスト３", "テスト３");
            dataGridView1.Rows.Add(false, "テスト４", "テスト４");
            dataGridView1.Rows.Add(false, "テスト５", "テスト５");
            dataGridView1.Rows.Add(false, "テスト６", "テスト６");

            dataGridView1.ClearSelection();
        }

        /// 
        /// データグリッドビューセルクリックイベント.
        /// 
        /// 
        /// 
        private void dataGridView1_CellClick(object sender, DataGridViewCellEventArgs e)
        {
            // ヘッダー以外
            if (e.RowIndex >= 0)
            {
                // クリックされた箇所を特定
                DataGridViewCell cell = dataGridView1.CurrentCell;
                if (cell.OwningColumn.Name == "Column1")
                {
                    if (cell.Value.ToString() == "False")
                    {
                        dataGridView1.Rows[e.RowIndex].SetValues(true);
                    }
                    else
                    {
                        dataGridView1.Rows[e.RowIndex].SetValues(false);
                    }
                }
                else
                {
                    if ((Control.ModifierKeys & Keys.Shift) == Keys.Shift)
                    {
                        return;
                    }

                    if ((Control.ModifierKeys & Keys.Control) == Keys.Control)
                    {
                        return;
                    }

                    // Shift or Ctrl キーが押されていなければクリック行以外をクリア
                    dataGridView1.ClearSelection();
                    dataGridView1.Rows[cell.RowIndex].Selected = true;

                }
            }
        }

        /// 
        /// データグリッドビュー選択変更イベント.
        /// 
        /// 
        /// 
        private void dataGridView1_SelectionChanged(object sender, EventArgs e)
        {
            // 選択されたセルを判定
            DataGridViewCell cell = dataGridView1.CurrentCell;
            if (cell.OwningColumn.Name != "Column1")
            {
                // 選択行のチェックボックスの状態を制御
                foreach (DataGridViewRow row in dataGridView1.Rows)
                {
                    if (row.Selected)
                    {
                        dataGridView1.Rows[row.Index].SetValues(true);
                    }
                    else
                    {
                        dataGridView1.Rows[row.Index].SetValues(false);
                    }
                }
            }
        }

    }
}

起動してみる

GIFイメージ

SCREENPRESSOでGIF動画を撮ってみました。

まとめ

前回のものがちょっと納得いかなかったので改めて。

DataGridViewに別のチェックボックスやコンボボックスを配置する要件なんて、
とりあえず需要があることだろうに標準で用意してほしいですよね。

昨日以上にサクッとしてますが以上です。

ではでは。

【C#】DataGridView の行選択時にチェックボックスの状態を変更する（その１）

2019-09-06T13:29:56+09:00

データグリッドビューにチェックボックスを配置して、
行を選択したらチェックの状態も一緒に変更するサンプル。

画面

Windows Form でプロジェクトを作成し、画面にデータグリッドビューを配置します。

先頭列をチェックボックス（DataGridViewCheckBoxColumn）にして、他は適当にテキストボックス列を2列を追加。

プロパティ

変更したプロパティはだいたい次のような感じ。

プロパティ
説明
デフォルト
変更後

AllowUserToResizeRows
ユーザーが列のサイズを変更できるかどうか
True
False

EditMode
セルの編集が開始される方法を決定するモード
EditOnKeystrokeOrF2
EditProgrammatically

SelectionMode
DataGridView のセルの選択方法
RowHeaderSelect
FullRowSelect

RowHeadersVisible
行ヘッダーを含んでいる列が表示されるかどうか
True
False

メソッド

メソッドは、「CellClick」のみ追加。

プログラム

using System;
using System.Collections.Generic;
using System.ComponentModel;
using System.Data;
using System.Drawing;
using System.Linq;
using System.Text;
using System.Threading.Tasks;
using System.Windows.Forms;

namespace SampleDataGridCheckbox
{
    public partial class Form1 : Form
    {
        public Form1()
        {
            InitializeComponent();

            dataGridView1.Rows.Add(false, "テスト１", "テスト１");
            dataGridView1.Rows.Add(false, "テスト２", "テスト２");
            dataGridView1.Rows.Add(false, "テスト３", "テスト３");
            dataGridView1.Rows.Add(false, "テスト４", "テスト４");
            dataGridView1.Rows.Add(false, "テスト５", "テスト５");
            dataGridView1.Rows.Add(false, "テスト６", "テスト６");

        }

        private void dataGridView1_CellClick(object sender, DataGridViewCellEventArgs e)
        {
            DataGridViewCheckBoxCell cell = (DataGridViewCheckBoxCell)dataGridView1[0, e.RowIndex];
            if (cell.Value.ToString() == "False")
            {
                dataGridView1.Rows[e.RowIndex].SetValues(true);
            }
            else
            {
                dataGridView1.Rows[e.RowIndex].SetValues(false);
            }
        }
    }
}

初期表示時に、テスト用のデータを6件ほど、データグリッドビューの行に追加。

起動してみる

無事に行を選択するとチェックされるようになりました。

まとめ

DataGridViewに表示するデータをDBから取得して、
DataSourceに設定するといった場合は、列の指定をインデックスではなく列名で指定した方が無難かと思います。

サクッとした話ですが以上。

ではでは。

「DataGridView」の記事 - Crieit

【VB.NET】DataGridView の行を動的に追加してみる

【VB.NET】DataGridView を直接変更してデータを更新してみる

【VB.NET】データグリッドビューでチェックされた行の背景色を変更する

【VB.NET】データグリッドビューで行毎のチェックボックスにイベントを仕込む

【VB.NET】データグリッドビューで行毎のコンボボックスにイベントを設定する

【VB.NET】データグリッドビューを動的に作成して行毎に違う内容のコンボボックスを表示する

【C#】DataGridView の 行選択時にチェックボックスの状態を変更する（その２）

【C#】DataGridView の 行選択時にチェックボックスの状態を変更する（その１）

【C#】DataGridView の行選択時にチェックボックスの状態を変更する（その２）

【C#】DataGridView の行選択時にチェックボックスの状態を変更する（その１）